home *** CD-ROM | disk | FTP | other *** search
/ NeXTSTEP 3.2 for Intel / NeXTSTEP 3.2 for Intel.iso / Upgrader.app / Default.upgrade / PostProcess < prev    next >
Encoding:
Text File  |  1993-10-15  |  7.7 KB  |  206 lines
  1. #!/bin/csh -f
  2. #
  3. # Upgrader post-processing script.
  4.  
  5. set     path = (/bin /usr/bin /etc /usr/etc /usr/ucb)
  6. unalias *
  7.  
  8. if ($#argv != 2) then
  9.     echo "Usage: PostProcess targroot sourceroot"
  10.     exit 1
  11. endif
  12.  
  13. set target = $argv[1]
  14. set source = $argv[2]
  15.  
  16. cd ${target}/etc/netinfo
  17. set databases = `ls ${target}/etc/netinfo`
  18.  
  19. foreach database ($databases)
  20.  
  21.     echo "Updating NetInfo database ${database}:"
  22.     set tag = `basename ${database} .nidb`
  23.     if ($tag == $database) then
  24.     echo "    ...but it's not a database.  Skipping."
  25.     continue
  26.     endif
  27.     if (${target}x != "/x") then
  28.     mv ${tag}.nidb XXXX.nidb
  29.     (/usr/etc/netinfod XXXX &) > /dev/null
  30.     set usetag = XXXX
  31.     else 
  32.     set usetag = $tag
  33.     endif
  34.     
  35.     # If root directory isn't writable, we probably aren't the master.
  36.     
  37.     niutil -createprop -t localhost/${usetag} / _thing _thing >& /dev/null
  38.     if ($status != 0) then
  39.         echo "    ...but this isn't the master server for it.  Skipping."
  40.     goto killdomain
  41.     else
  42.         niutil -destroyprop -t localhost/${usetag} / _thing
  43.     endif
  44.  
  45.     echo -n "    Updating user accounts..."
  46.     set nacct = `niutil -t -list localhost/${usetag} /users | awk '{print $2}' | ${source}/Upgrader.app/Default.upgrade/FixUsers ${usetag}`
  47.     echo "$nacct accounts"
  48.     
  49.     echo "    Creating /locations/renderers..."
  50.     niutil -t -list localhost/${usetag} /locations/renderers >& /dev/null
  51.     if ($status != 0) then
  52.     niutil -t -create localhost/${usetag} /locations/renderers >& /dev/null
  53.     niutil -t -createprop localhost/${usetag} /locations/renderers _writers '*' >& /dev/null
  54.     niutil -t -create localhost/${usetag} /locations/renderers/localhost >& /dev/null
  55.     niutil -t -createprop localhost/${usetag} /locations/renderers/localhost _writers '*' >& /dev/null
  56.     niutil -t -createprop localhost/${usetag} /locations/renderers/localhost note "Local Renderer" >& /dev/null
  57.     endif
  58.  
  59.     echo "    Updating /rpcs..."
  60.     niutil -t -list localhost/${usetag} /rpcs/renderd >& /dev/null
  61.     if ($status != 0) then
  62.     niutil -t -create localhost/${usetag} /rpcs/renderd >& /dev/null
  63.     niutil -t -createprop localhost/${usetag} /rpcs/renderd number 200100002 >& /dev/null
  64.     niutil -t -destroyprop localhost/${usetag} /rpcs/rexd number >& /dev/null
  65.     niutil -t -destroy localhost/${usetag} /rpcs/rexd >& /dev/null
  66.     endif
  67.     
  68.     echo "    Removing decode alias..."
  69.     niutil -t -destroyprop localhost/${usetag} /aliases/decode members >& /dev/null
  70.     niutil -t -destroy localhost/${usetag} /aliases/decode >& /dev/null
  71.  
  72.     if ($tag == "local") then
  73.     echo "    Creating /localconfig..."
  74.     niutil -t -list localhost/${usetag} /localconfig >& /dev/null
  75.     if ($status != 0) then
  76.         niutil -t -create localhost/${usetag} /localconfig
  77.     endif
  78.     # Make sure old language and keyboard dirs aren't around.
  79.     niutil -t -destroy localhost/${usetag} /localconfig/language >& /dev/null
  80.     niutil -t -destroy localhost/${usetag} /localconfig/keyboard >& /dev/null
  81.     niutil -t -list localhost/${usetag} /screens >& /dev/null
  82.     if ($status == 0) then
  83.         set screens = `niutil -t -list localhost/${usetag} /screens | awk '{print $2}'`
  84.         foreach screen ($screens) 
  85.         foreach prop (slot unit bounds active) 
  86.             set value = `niutil -read . /screens/$screen | grep $prop | awk -F: '{print $2}'`
  87.             niutil -t -destroyprop localhost/${usetag} /screens/$screen $prop
  88.         end
  89.         niutil -t -destroyprop localhost/${usetag} /screens/$screen _writers >& /dev/null
  90.         niutil -t -destroy localhost/${usetag} /screens/$screen
  91.         end 
  92.         niutil -t -destroy localhost/${usetag} /screens
  93.     endif
  94.     if (-f ${target}/private/etc/exports && ! -f ${target}/private/etc/exports.old) then
  95.         echo "    Converting /etc/exports to NetInfo..."
  96.         ${source}/Upgrader.app/loadexports -t exports localhost/${usetag} < ${target}/private/etc/exports
  97.         mv ${target}/private/etc/exports ${target}/private/etc/exports.old
  98. cat > ${target}/private/etc/exports << XXX
  99. # THIS FILE IS OBSOLETE.  NFS exports are now stored in NetInfo.
  100. #
  101. # To export disks, use the NFSManager application located in /NextAdmin. 
  102. # You can also niload an old-format exports file, or add the entries
  103. # to the /exports directory of your local NetInfo domain by hand.
  104. #
  105. # Your old /etc/exports has been saved in /etc/exports.old.
  106. XXX
  107.     endif
  108.     endif
  109.     
  110.     killdomain:
  111.     
  112.     if (${target}x != "/x") then
  113.     set pid = `ps ax | grep "netinfod XXXX" | grep -v grep | awk '{print $1}'`
  114.     kill -TERM $pid
  115.     mv XXXX.nidb ${tag}.nidb
  116.     endif
  117.     
  118. end
  119.  
  120. echo -n "NetInfo changes complete. "
  121.  
  122. foreach language (French German Italian Swedish Spanish English Japanese)
  123.     /bin/rm -rf ${target}/NextLibrary/Receipts/${language}.pkg
  124. end
  125.     
  126. if ( -d ${source}/NextCD/Packages ) then
  127.     echo "Checking sizes for languages..."
  128.     set freekbytes = `df ${target} | tail -1 | awk '{print $4}'`
  129.     set langkbytes = 0
  130.     cd ${source}/NextCD/Packages
  131.     foreach i (French German Italian Swedish Spanish English Japanese)
  132.         if ( -d ${i}.pkg ) then
  133.         set size = `du -s ${source}/NextCD/Packages/${i}.pkg | awk '{print $1}'`
  134.         @ langkbytes +=  ${size}
  135.     endif
  136.     end
  137.     echo "Languages require ${langkbytes}K, and ${freekbytes}K are available."
  138.     if ( $freekbytes > ($langkbytes + 1000) ) then
  139.         echo -n "Installing languages..."
  140.     mkdirs ${target}/NextLibrary/Receipts
  141.     cd ${source}/NextCD/Packages
  142.     foreach i (French German Italian Swedish Spanish English Japanese)
  143.         if ( -d ${i}.pkg ) then
  144.         echo -n "${i}, "
  145.         tar cf - ${i}.pkg | (cd ${target}/NextLibrary/Receipts; tar xf -)
  146.         echo "/" > ${target}/NextLibrary/Receipts/${i}.pkg/${i}.location
  147.         echo "compressed" > ${target}/NextLibrary/Receipts/${i}.pkg/${i}.status
  148.         endif
  149.     end
  150.     echo "done."
  151.     else
  152.         echo "There isn't enough space to install all the languages."
  153.     if ( -d ${ROOT}/NextCD/Packages/English.pkg ) then
  154.         echo "Checking sizes for English help..."
  155.         set langkbytes=`du -s ${source}/NextCD/Packages/English.pkg | awk '{print $1}'`
  156.         echo "English help requires ${langkbytes}K, and ${freekbytes}K are available."
  157.         if ( $freekbytes > `expr $langkbytes + 1000` ) then
  158.         echo "Installing English help..."
  159.         mkdirs ${target}/NextLibrary/Receipts
  160.         cd ${source}/NextCD/Packages
  161.         tar cf - English.pkg | (cd ${target}/NextLibrary/Receipts; tar xfp -)
  162.         echo "/" > ${target}/NextLibrary/Receipts/English.pkg/English.location
  163.         echo "compressed" > ${target}/NextLibrary/Receipts/English.pkg/English.status
  164.         else
  165.         echo "There isn't enough space to install English help."
  166.         endif
  167.     endif
  168.     endif
  169. else
  170.     echo ""
  171. endif
  172.  
  173. if (-d ${target}/usr/Devices) then
  174.     echo "Moving old drivers..."
  175.     mkdirs ${target}/UpdatedFiles
  176.     mv ${target}/usr/Devices ${target}/UpdatedFiles/3.1Drivers
  177.     foreach i (EpsonWingineDriver SCSITapeDriver EtherExpressDriver SerialPortDriver AutoHostAddPatch ATIDriver DBKitPrerelease EuroKeymaps IntelGXAudio Interceptor S3Driver)
  178.         rm -rf ${target}/NextLibrary/Receipts/${i}.pkg
  179.     end
  180.     echo "Installing drivers..."
  181.     /bin/cp -r ${source}/usr/Devices ${target}/usr
  182. endif
  183.  
  184.  
  185. if (-d ${target}/usr/Devices) then
  186.     echo "Upgrading drivers..."
  187.     ${source}/Upgrader.app/DriverUpgrade ${target}/UpdatedFiles/3.1Drivers ${target}/usr/Devices
  188.     /bin/cp ${target}/UpdatedFiles/3.1Drivers/System.config/*.custom ${target}/usr/Devices/System.config
  189.     foreach i ( ${target}/UpdatedFiles/3.1Drivers/*.config )
  190.     mv ${i} ${i}_3.1
  191.     end
  192.     set LANGUAGE = `awk -F'=' 'NR==2 {print $2}' ${target}/usr/Devices/System.config/CDIS.custom`
  193.     echo '"Language" = "'${LANGUAGE}'";' >> ${target}/usr/Devices/System.config/Default.table
  194.     echo '"Language" = "'${LANGUAGE}'";' >> ${target}/usr/Devices/System.config/Instance0.table
  195. echo "Driver upgrade complete."
  196. endif
  197.  
  198. # Delete empty nib, if it exists.
  199. rm -rf /usr/lib/NextStep/loginwindow.app/English.lproj/login.nib
  200.  
  201. echo -n "Postprocessing complete at "
  202. date
  203. echo "Upgrade complete."
  204.  
  205. exit 0
  206.